project('meson-test', 'cpp',
  version : '0.1',
  default_options : ['warning_level=3', 'cpp_std=c++11']
)

# Libraries

# libxml2
libxml2_proj = subproject('libxml2', default_options: ['python=false', 'default_library=static'])
libxml2_dep = libxml2_proj.get_variable('xml_dep')

# poco
cmake = import('cmake')
opt_var = cmake.subproject_options()
opt_var.add_cmake_defines({ 'POCO_STATIC': true, 'ENABLE_MONGODB': false, 'ENABLE_REDIS': false, 
                            'ENABLE_DATA_SQLITE': false, 'ENABLE_DATA_MYSQL': false, 'ENABLE_DATA_ODBC': false,
                            'ENABLE_ZIP': false, 'ENABLE_PAGECOMPILER': false, 'ENABLE_PAGECOMPILER_FILE2PAGE': false,
})
poco_proj = cmake.subproject('poco', options: opt_var)
poco_dep_foundation = poco_proj.dependency(['Foundation'])
poco_dep_util = poco_proj.dependency(['Util'])


# Include directories
incdir = include_directories('include')

# Executable
executable('mesontest',
           'src/libxml_meson.cpp',
           'src/poco.cpp',
           'src/main.cpp',
           dependencies: [libxml2_dep, poco_dep_foundation, poco_dep_util],
           include_directories : incdir
)